Docs  /  NAVAX Sachpostenausgleich  /  Informationen für Entwickler

 Zusätzliche Buch.-Blätter

2024/12/03 • 2 Min. Lesedauer
Standardmäßig ist der NAVAX Sachpostenausgleich über pageextensions bereits in einige Buch.-Blätter integriert. Der Code ist in allen Buch.-Blättern identisch. Somit kann der NAVAX Sachpostenausgleich über eine Individualprogrammierung auch in anderen Buch.-Blättern mit wenig Aufwand zur Verfügung gestellt werden. Nachfolgend der Code für die Integration am Beispiel der Fibu Buch.-Blätter.

pageextension 70714681 "NVXGLA General Journal" extends "General Journal"
{
    ContextSensitiveHelpPage = 'Journal';

    layout
    {
        modify("Account Type")
        {
            trigger OnAfterValidate();
            begin
                NVXGLAEnableApplyGLEntriesAction();
            end;
        }
        modify("Bal. Account Type")
        {
            trigger OnAfterValidate();
            begin
                NVXGLAEnableApplyGLEntriesAction();
            end;
        }
        addafter("Applies-to ID")
        {
            field("NVXGLA Applies-to Doc. Type"; Rec."NVXGLA Applies-to Doc. Type")
            {
                ApplicationArea = All;
                ToolTip = 'Gibt die Art des gebuchten Belegs an, mit dem dieser Beleg oder die Buch.-Blattzeile beim Buchen ausgeglichen wird.';
                Visible = false;
            }
            field("NVXGLA Applies-to Doc. No."; Rec."NVXGLA Applies-to Doc. No.")
            {
                ApplicationArea = All;
                ToolTip = 'Gibt die Nummer des gebuchten Belegs an, mit dem dieser Beleg oder die Buch.-Blattzeile beim Buchen ausgeglichen wird.';
                Visible = false;
            }
            field("NVXGLA Applies-to ID"; Rec."NVXGLA Applies-to ID")
            {
                ApplicationArea = All;
                ToolTip = 'Gibt die ID der Posten an, die ausgeglichen werden, wenn Sie die Aktion ''GLA Sachposten ausgleichen'' auswählen.';
                Visible = false;
            }
        }
    }

    actions
    {
        addafter("Apply Entries")
        {
            action(NVXGLAApplyEntriesAction)
            {
                ApplicationArea = All;
                Caption = 'GLA Sachposten ausgleichen';
                Ellipsis = true;
                Enabled = NVXGLAApplyGLEntriesActionEnabled;
                Image = ApplyEntries;
                RunObject = Codeunit "NVXGLA Gen. Jnl.-Apply";
                ShortCutKey = 'Alt+F11';
                ToolTip = 'Gleichen Sie mit dem Betrag einer Buch.-Blattzeile einen oder mehrere Sachposten aus.';
            }
        }
        addafter("Apply Entries_Promoted")
        {
            actionref(NVXGLAApplyEntriesAction_Promoted; NVXGLAApplyEntriesAction)
            {
            }
        }
    }

    var
        NVXGLAApplyGLEntriesActionEnabled: Boolean;

    trigger OnAfterGetRecord()
    begin
        NVXGLAEnableApplyGLEntriesAction();
    end;

    trigger OnAfterGetCurrRecord();
    begin
        NVXGLAEnableApplyGLEntriesAction();
    end;

    trigger OnNewRecord(BelowxRec: Boolean);
    begin
        NVXGLAEnableApplyGLEntriesAction();
    end;

    local procedure NVXGLAEnableApplyGLEntriesAction()
    begin
        NVXGLAApplyGLEntriesActionEnabled :=
            (Rec."Account Type" = Rec."Account Type"::"G/L Account") or
            (Rec."Bal. Account Type" = Rec."Bal. Account Type"::"G/L Account");
    end;
}